Double if statement in excel

I’m not expert in excel programming and I want to write this formula in excel:

• If A10 is "Hello" and H10 is blank, it returns D7x5.5, else it should return D8x5.5
• If A10 is "Hello" and H10 is not blank, it returns D7xH10, else it should return D8xH10

thanks for support.

>Solution :

You could try using the following formula:

=IFS(
    AND(
        A10 = "Hello" ,H10 = ""
    ) ,D7 * 5.5,
    AND(
        A10 <> "Hello" ,H10 = ""
    ) ,D8 * 5.5,
    AND(
        A10 = "Hello" ,H10 <> ""
    ) ,D7 * H10,1,D8 * H10
)

The above formula takes into account about all the conditions outlined in the OP:

• If A10 is "Hello" and H10 is blank, it returns D7x5.5, else it should return D8x5.5

• If A10 is "Hello" and H10 is not blank, it returns D7xH10, else it should return D8xH10

For Older Versions:

=IF(
    AND(
        A10 = "Hello" ,H10 = ""
    ) ,D7 * 5.5,
    IF(
        AND(
            A10 <> "Hello" ,H10 = ""
        ) ,D8 * 5.5,
        IF(
            AND(
                A10 = "Hello" ,H10 <> ""
            ) ,D7 * H10,D8 * H10
        )
    )
)

As per comments of OP, they are using Excel in Italian Version, therefore here is the version alternative:

=SE(E(A10="Hello";H10="");D7*5,5;SE(E(A10<>"Hello";H10="");D8*5,5;SE(E(A10="Hello";H10<>"");D7*H10;D8*H10)))